package de.sb12.matthias.playground.mathabs {
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.utils.getTimer;
 
	/**
	 * creation date: 07.08.2009
	 * @author Matthias Dehmel
	 *
	 * modified by $Author$ on $Date$
	 * @version $Id$
	 */
	public class MathAbsPerformance extends Sprite {
		private const TESTRUNS : uint = 200000;
		private var _log : TextField;
 
		public function MathAbsPerformance() {
			_log = new TextField( );
			_log.width = 500;
			_log.autoSize = TextFieldAutoSize.LEFT;
			_log.wordWrap = true;
			_log.multiline = true;
			_log.x = _log.y = 20;
			addChild(_log);
 
			mathAbs();
			manualMathAbs();
			inlineManualMathAbs();
			bitshift();
		}
 
		private function mathAbs() : void {
			var start : Number = getTimer();
			var num : Number;
			var i : int = 0;
			for (i; i < TESTRUNS ; i++)
				num = Math.abs( 5 );
 
			log('Math.abs', getTimer( ) - start );
		}
 
		private function manualMathAbs() : void {
			var start : Number = getTimer();
			var num : Number;
			var i : int = 0;
			for (i; i < TESTRUNS ; i++)
				num = abs( 5 );
 
			log('manual abs', getTimer( ) - start );
		}
 
		private function abs( value : Number ) : Number {
			return ( value < 0 ) ? -value : value;
		}
 
		private function inlineManualMathAbs() : void {
			var start : Number = getTimer();
			var num : Number = 5;
			var i : int = 0;
			for (i; i < TESTRUNS ; i++)
				num = ( num < 0 ) ? -num : num;		
 
			log('manual inline abs', getTimer( ) - start );
		}
 
		private function bitshift() : void {
			var start : Number = getTimer();
			var num : Number = 5;
			var i : int = 0;
			for (i; i < TESTRUNS ; i++)
                                   num = ( num^( num >> 31 ) ) - ( num >> 31 );
 
			log('bitshift', getTimer( ) - start );
		}
 
		private function log( type : String, time : uint ) : void {
			_log.appendText( '\n' + type + ': ' + time.toString() + 'ms' );
		}
	}
}